wzorzec { akcja }

awk 'program' plik1 plik2 ...

awk -f program plik1 plik2 ...

Struktura pliku wejściowego

Chardonnay Lyngrove   RPA białe wytrawne 95.00 131
Cabernet Sauvignon Merlot Lyngrove   RPA czerwone wytrawne 95.00 58
Baron De France   Fra białe wytrawne 25.00 289
Anjou Blanc Chenin   Fra białe wytrawne 33.00 392
Anjou D'rose   Fra   różowe półwytrawne 33.00 207
Anjou Rouge Cabernet  Fra czerwone półwytrawne 33.00 266
Bordeaux Graveschateau Saint Galier Fra białe wytrawne 89.00 144
Marquis De Chasse 1996 Fra czerwone wytrawne 55.00 229
Don Kichot Tinto Spa czerwone półwytrawne 25.00 360
Rioja Miralcampo   Spa czerwone   wytrawne 62.00 210
Rioja Miralcampo   Spa białe wytrawne 62.00 179
Sherry Rich Cream   Spa czerwone słodkie 109.00  55
Sole D'italia   Ita czerwone wytrawne  25.00 666
Valpolicella   Ita czerwone wytrawne 45.00 370
Chianti Villa Bellafonte  Ita czerwone wytrawne 68.00 131
Asti Spumante Docg   Ita białe półsłodkie 51.00 207
Moscato Spumante Vsq   Ita białe słodkie 26.00 629

Skrypty wykonywalne

#!/usr/bin/awk -f
NR <= 10

Wzorce

BEGIN/END

Wyrażenie

$(NF-4) == "Fra" { print $0 } # Wydrukuj wina francuskie

$(NF-4) == "Fra" # Wydrukuj wina francuskie

$NF * $(NF-1) > 10000 # Wydrukuj najlepiej kupowane

Uwagi: Znak # rozpoczyna komentarz -- wszystko od znaku # do końca wiersza jest przez AWK ignorowane.

Wzorzec regularny

/r/

Pasuje do bieżącego wiersza z pliku wejściowego jeżeli zawiera ona podnapis pasujący do wyrażenia regularnego r.

wyrażenie ~ /r/

Pasuje do napisu będącego wartością wyrażenia jeżeli zawiera on podnapis pasujący do wyrażenia regularnego r. Zapis /r/ jest równoważny formie $0 ~ /r/.

wyrażenie !~ /r/

Pasuje do napisu będącego wartością wyrażenia jeżeli nie zawiera on podnapisu pasującego do wyrażenia regularnego r.

$(NF-2) ~ /wytrawne/ # wydrukuj coś wytrawnego

$(NF-2) == "wytrawne" # wydrukuj wytrawne
$(NF-2) == "półwytrawne" # ... i półwytrawne

Wzorzec złożony

$(NF-2) == "wytrawne" || $(NF-2) == "półwytrawne" # coś wytrawnego

$(NF-4) == "Fra" && $(NF-1) * $NF > 10000

Wzorzec z przecinkiem

$3 ~ /Briancon/, $3 ~ /Morzine/

$3 ~ /Draguignan/, $3 ~ /Briancon/

Wyrażenia regularne

/(Ali|ali)(baba|gator)/ 

<tr align="left"><td>Chardonnay Lyngrove</td><td>RPA</td></tr>

NR==1, /^-+[ \t]*$/ { next }  # Pomiń nagłówek,
NF < 1 { next }               # puste wiersze
/^Etap[ \t]+[0-9]+:/ { next } # oraz nagłówki etapów
$(NF-1) > 1000 # Wydrukuj podjazd o różnicy > 1000

Napisy jako wyrażenia regularne

BEGIN {cyfry="^[0-9]+$" }; $0 ~cyfry 

Wyrażenia

Stałe

Zmienne

Zmienne wbudowane

gawk 'BEGIN {print ENVIRON["HOME"] }'

Uwagi: Zmienna FILENAME zawiera nazwę bieżącego pliku wejściowego. Oznacza to, że w obrębie wzorców BEGIN i END wartość FILENAME jest nieokreślona.

Zmienne przechowujące zawartości pól

Operatory arytmetyczne

Operatory napisowe

y = "Ali"; z = "gator"; x1 = y "ba" "ba"; x2=  y z;

Operatory porównywania i operatory logiczne

function leapyear(year) {
   return year %4 == 0 && year % 100 \
   != 0 || year%400 ==0; }

BEGIN {print leapyear(1996), leapyear(1806),
   leapyear(1066)}

Uwagi: Bardzo długa instrukcja może zostać podzielona i zapisana w kilku wierszach. Znakiem kontynuacji jest \, bezpośrednio przed znakiem końca wiersza (por. drugi wiersz przykładu). Jeżeli wiersz kończy się przecinkiem (por. wiersz przedostatni) to znak kontynuacji jest opcjonalny.

Operatory pasowania do wyrażeń regularnych

Przypisanie

#!/usr/bin/awk -f
{obrot = $NF * $(NF-1); oo += obrot }
$(NF - 3) ~ /białe/ {biale += obrot } 
$(NF - 3) ~ /czerwone/ {czerwone += obrot } 
END { print "Obrót razem:", oo ", w tym: czerwone:", 
      czerwone ", białe:", biale "."; } 

Operator warunkowy ?:

wyrażenie1 ? wyrażenie2 : wyrażenie3

{print $1!=0 ? 1/$1 : "Zero w wierszu", NR;}

Arytmetyczne funkcje wbudowane

Napisowe funkcje wbudowane

Funkcje daty i czasu

systime()

strftime(format, czas)

Instrukcje sterujące

if (wyrażenie)
instrukcja1
else
instrukcja2

if (e1) if (e2) s=1; else s=2

---

Instrukcje sterujące

---

{ instrukcje }

grupowanie instrukcji.

if (w) instrukcja

jeśli wyrażenie w jest prawdziwe wykonaj instrukcję.

if (w) instrukcja1 else instrukcja2

wykonaj instrukcję1 jeśli wyrażenie w jest prawdziwe, w wypadku przeciwnym instrukcję2.

while (w) instrukcja

jeśli wyrażenie w jest prawdziwe wykonaj instrukcję i powtórz.

for (w1; w2; w3) instrukcja

równoważne instrukcji: w1; while (w2) {instrukcja; w3}.

for (zmienna in tablica) instrukcja

instrukcja jest wykonywana dla zmiennej przyjmującej kolejno wartości każdego elementu tablicy.

do instrukcja while (w)

wykonaj instrukcję i jeżeli wyrażenie w jest prawdziwe powtórz.

break

natychmiastowe wyjście z pętli while, for, do.

continue

rozpocznij następną iterację w pętlach while, for, do.

next

rozpoczęcie następnej iteracji głównej pętli wejściowej. (Przez główną pętlę wejściową rozumiemy mechanizm AWK do analizowania rekord po rekordzie pliku wejściowego.)

exit wyrażenie

sterowanie jest przekazywane bezpośrednio do akcji END. Jeśli polecenia exit użyto w akcji END, program kończy działanie. Opcjonalne wyrażenie zwracane jest jako status zakończenia programu.

nextfile*

zakończenie przeglądania bieżącego pliku i przejście do przeglądania następnego z podanych w linii poleceń, lub (dla ostatniego pliku) przejście do wzorca END. W wyniku wykonania nextfile* zmienia się wartość zmiennej FILENAME, wartością FNR staje się jeden a wartość ARGIND* jest zwiększana o jeden.

NR == 1 { omax = $NF * $(NF -1); } # inicjalizacja omax
{ o = $NF * $(NF -1);
  if (omax < o ) { omax = o; f = $0; }
  else { if (omax == o) {f = f "\n" $0 } }
}
END {print omax; print f }

Instrukcja pusta

BEGIN { FS = "\t" } # Pola oddziela znak tabulacji!
{ for (i=1; i <= NF && $i!=""; i++)
   ;
  if (i <= NF) { print }
}

Tablice asocjacyjne

{for (i=1; i <= NF; i++) {ls[$i]++}}

for (zmienna in tablica) instrukcja

END {for (word in ls)  print word, ls[word]  }

indeks in tablica

if ("Alibaba" in ls) {print "OK!"}
else {print "KO!"}

Instrukcja delete

delete tablica[indeks]

{ obrot[$(NF-2)] += $NF * $(NF-1) }
END { for (wino in obrot) { print wino, obrot[wino] }}

Tablice wielowymiarowe

for (i=1; i <= 10; i++)
   for (j=1; j <= 10; j++)
      r[i,j] = rand();

for ((i,j) in r) {...}

for (k in r) {print r[k]}

Uwagi: Elementy tablic nie mogą być tablicami.

{  o = $NF * $(NF-1); # obliczamy obrót 
   smaki[$(NF-2)] += o; # obrót wg. smaków
   kolory[$(NF-3)] += o; # obrót wg. kolorów
   obrot[$(NF-2), $(NF-3)] += o # obrót wg. smaków i kolorów
}
END { for (smak in smaki) {
         print smak, "...", smaki[smak]; 
         razem +=smaki[smak]; 
         for (kolor in kolory) {
              if ((smak, kolor) in obrot)
                print "--", kolor, "...", obrot[smak, kolor];
       } }
    print "Razem ...", razem;
}

Funkcje

function nazwa (lista-argumentów) {
   lista-instrukcji }

Wejście

awk -f program plik

Pola

BEGIN {FS ="[,;:]"}

Uwagi: Wartość zmiennej FS może zostać nadana także z poziomu uruchomienia AWK za pomocą przełącznika -F. Przykładowo zamiast powyższego wzorca BEGIN moglibyśmy napisać w linii poleceń:

awk -F'[,;:]' -f program plik

Rekordy

Instrukcja getline

while (getline < plik > 0) {...}

while ("ls -l" | getline > 0) {...}

close (plik); close("ls -lrt")

BEGIN { niema = 1; DUZY = 1000000
   while ("ls -l" | getline)
      if (NF == 9  && $5 > DUZY) {print $0; niema =0 }
   if (niema) {print "Nie ma plików większych od", DUZY; }
}

function getdate(x, date) {
   "date" | getline x;  split(x, date, " ");
   DAT["year"]= date[6]; DAT["mon"]= date[2]; DAT["day"]= date[3];
   return;
}
# Przykład wykorzystania funkcji getdate:
BEGIN {getdate(); print DAT["mon"], DAT["day"] }

Pola o ustalonej długości

# Drukuj nazwę góry i jej długość
BEGIN  { FIELDWIDTHS = "1 25 5 5 4 3 4 4 4 4 4" }
NR==1, /^-+[ \t]*$/ { next }
/^Etap[ \t]+[0-9]+:/ { next }
NF > 0 { print $2, $11 }

Uwagi: Zwróćmy uwagę, że gawk nie dokonuje żadnego sprawdzenia poprawności specyfikacji podanej w napisie FIELDWIDTHS*.

Instrukcje wyjścia -- print/printf

Instrukcja printf

printf (format, arg1,arg2,...)

• -, zawartość pola jest justowana do lewego krańca pola;

• ciąg-cyfr, określający minimalny rozmiar pola (w znakach). Przekształcony argument będzie wpisany do pola o długości co najmniej równej ciąg-cyfr. Jeżeli argument składa się z mniejszej liczby znaków, to będzie ono uzupełnione do długości minimalnej odstępami. Jeżeli specyfikacja długości rozpoczyna się cyfrą 0, to pole będzie wypełniane nie znaczącymi zerami;

• .ciąg-cyfr, maksymalna drukowana długość napisu lub liczba cyfr po kropce dziesiętnej.

Instrukcja print

awk 'BEGIN {OFS=":";ORS="->"; print log(2), log(3); print log(5); }'

0.693147:1.09861->1.60944->

Uwagi: print to skrót od print $0 (a nie, jak można by się spodziewać, print ORS).

Drukowanie do plików

printf format, arg1,... > plik
print arg1,... > plik

printf format, arg1,... >> plik
print arg1,... >> plik

{ printf "%s\n", $0 > $1 }

Drukowanie w potoku

printf format, arg1,... | program
print arg1,... | program

{ obrot[$(NF-2)] += $NF * $(NF-1) }
END {for (wino in obrot) {print wino, obrot[wino] | "sort -nr +1" }}

Funkcja close

close(napis)

#!/usr/bin/awk -f
NR==1, /^-+[ \t]*$/ { next }  # Pomiń nagłówek,
/^Etap[ \t]+[0-9]+:/ { close(File);
    sub(/:/,"",$2); File="etap" $2;
    next } 
NF > 0 { print $0 > File}

#!/bin/bash
if [ ! -f "$1" ]; then 
echo "Wykorzystanie: `basename $0`: plik" >&2; exit 0; fi
awk 'FNR==1 { pass++ }
pass == 1 {oo += $NF * $(NF-1) } 
pass == 2 {print $0, 100 * $NF * $(NF-1)/oo }' $1 $1

Funkcja fflush*

fflush(napis)

Funkcja system

system(instrukcja)

Argumenty wywołania programu

gawk -v v=1 -f 1.awk test.txt v=1 b

BEGIN {for (i=0; i< ARGC; i++) {print ARGV[i]}  }

BEGIN{ ARGV[1]="test.txt"; if (ARGC < 2) {ARGC = 2} }

Uruchamianie AWK